AnGelBot-Portal²

AnGelBot-Portal² > Scripting > Scriptreleases > AntiAd Script v1.00 by Spiky
Normale Version: AntiAd Script v1.00 by Spiky
Du siehst gerade eine vereinfachte Darstellung unserer Inhalte. Normale Ansicht mit richtiger Formatierung.
Seiten: 1 2

Christian

11.12.2005, 22:58 Uhr
AntiAd Script v1.0 by Spiky

Beschreibung:
AntiAd = Anti Advertise dt. gegen Werbung . . . dieses Script reagiert auf Channel Werbung. Es Warnt, Kickt oder Kickbant einen User aus dem Channel und Joint sogar noch den geworbenen Channel um die Werbung zu rächen und macht dann in dem geworbenen Channel Werbung für deinen Channel und partet anschließend wieder.
Hinweis: (Dieses Script funktioniert mit dem Standart Trigger vom AngelBot, ihr könnt ihn unter .botsetup ... 21 ... ändern.)

Installation:
Einfach Script laden.

Commands:
  • !antiad <on/off> - (Schaltet das Script an/aus)
  • !antiad add <#chan> - (damit added Ihr Channels für die Werbung gemacht werden darf)
  • !antiad del <#chan> - (damit entfernt Ihr diese wieder)
  • !antiad reakt <warn/kick/kickban> - (Hiermir bestimmt Ihr was bei einem Advertise passieren soll)
  • !antiad bantime <minutes> - (Hiermit setzt Ihr die BanZeit bei einem Advertise)
  • !antiad advertise <on/off> - (Hiermit schaltet Ihr die RE-Advertise Funktion an/aus

Code:
'##################################################
'## AntiAd Script v1.0                           ##
'##################################################
'## Copyright 2005 by Spiky                      ##
'##################################################
'## Christian Hetkamp                            ##
'## spiky@spiky-page.de                          ##
'## www.spiky-page.de                            ##
'##################################################

Sub Init()
  Script "AntiAd Script by Spiky"
  Hook "Chan_Msg"
End Sub

Const INI = "AntiAd.ini"

Sub Chan_Msg(Chan, Nick, RegUser, Line)
  Dim AdChan, Status, Advertise, BanTime, Channels
  Status = ReadINIString(Chan, "Status", "0", INI)
  BanTime = ReadINIString(Chan, "BanTime", "0", INI)
  Advertise = ReadINIString(Chan, "Advertise", "0", INI)
  Channels = ReadINIString(Chan, "Channels", vbNullString, INI)
  If (LCase(Param(Line, 1)) = CommandPrefix & "antiad") And MatchFlags(GetUserChanFlags(RegUser, Chan), "+n") Then
    Select Case LCase(Param(Line, 2))
      Case "on"
          WriteINIString Chan, "Status", "1", INI
          SendLine "Notice " & Nick & " :AntiAd (Enabled) successfully.", 3
      Case "off"
          WriteINIString Chan, "Status", "0", INI
          SendLine "Notice " & Nick & " :AntiAd (Disabled) successfully.", 3
      Case "add"
        If InStr(1, " " & Channels & " ", " " & Param(Line, 3) & " ", vbTextCompare) = 0 Then
          Channels = Trim3(Channels & " " & Param(Line, 3))
          WriteINIString Chan, "Channels", Channels, INI
          SendLine "Notice " & Nick & " :AntiAd allowed Channel (" & Param(Line, 3) & ") added successfully.", 3
        Else
          SendLine "Notice " & Nick & " :AntiAd allowed Channel (" & Param(Line, 3) & ") is already added", 3
        End If
      Case "del"
        If InStr(1, " " & Channels & " ", " " & Param(Line, 3) & " ", vbTextCompare) > 0 Then
          Channels = Trim3(Replace(LCase(Channels), LCase(Param(Line, 3)), vbNullString))
          WriteINIString Chan, "Channels", Channels, INI
          SendLine "Notice " & Nick & " :AntiAd allowed Channel (" & Param(Line, 3) & ") deleted successfully.", 3
        Else
          SendLine "Notice " & Nick & " :AntiAd allowed Channel (" & Param(Line, 3) & ") is not known to me", 3
        End If
      Case "chanlist"
          SendLine "Notice " & Nick & " :AntiAd allowed Channels (" & Channels & ")", 3
      Case "bantime"
        WriteINIString Chan, "BanTime", Param(Line, 3), INI
        SendLine "Notice " & Nick & " :AntiAd BanTime (" & Param(Line, 3) & ")", 3
      Case "advertise"
        Select Case LCase(Param(Line,3))
          Case "on"
            WriteINIString Chan, "Advertise", "1", INI
            SendLine "Notice " & Nick & " :AntiAd ReAdvertise (Enable) successfully.", 3
          Case "off"
            WriteINIString Chan, "Adertise", "0", INI
            SendLine "Notice " & Nick & " :AntiAd ReAdvertise (Disable) successfully.", 3
          End Select
      Case "reakt"
        Select Case LCase(Param(Line,3))
          Case "warn"
            WriteINIString Chan, "Reakt", "0", INI
            SendLine "Notice " & Nick & " :AntiAd Reakt (Warn)", 3
          Case "kick"
            WriteINIString Chan, "Reakt", "1", INI
            SendLine "Notice " & Nick & " :AntiAd Reakt (Kick)", 3
          Case "kickban"
            WriteINIString Chan, "Reakt", "2", INI
            SendLine "Notice " & Nick & " :AntiAd Reakt (KickBan)", 3
        End Select
    End Select
  ElseIf (Status = 1) And (Not IsOp(Nick, Chan)) Then
    Do While InStr(Line, "#")
      Line = Mid(Line, InStr(Line, "#"))
      AdChan = Param(Line, 1)
      Line = Mid(Line, Len(Param(Line, 1)) + 1)
      If AdChan = Chan Then Exit Sub
      If IsOn(MyNick, AdChan) Then Exit Sub
      If (InStr(1, " " & Channels & " ", " " & AdChan & " ", vbTextCompare) = 0) And Len(AdChan) > 1 Then
        Select Case ReadINIString(Chan, "Reakt", "0", INI)
          Case "0"
            SendLine "Notice " & Nick & " :Don't Advertise in (" & Chan & ")", 3
          Case "1"
            SendLine "KICK " & Chan & " " & Nick & " :Don't Advertise in (" & Chan & ")", 1
          Case "2"
            TimedCommand "Unban " & Chr(34) & Chan & Chr(34) & ", " & Chr(34) & Mask(Hostmask(Chan, Nick), 1) & Chr(34), BanTime * 60
            SendLine "MODE " & Chan & " -o+b " & Nick & " " & Mask(Hostmask(Chan, Nick), 1), 1
            AddKick Chan, Nick, "Don't Advertise in (" & Chan & ") Banned for (" & BanTime & ") Minutes."
        End Select
        If Advertise = 1 Then
          SendLine "JOIN " & AdChan, 1
          SendLine "PRIVMSG " & AdChan & " :Hi (" & Nick & ") Advertised in (" & Chan & ") please Join the Channel", 2
          SendLine "PART " & AdChan & " :Joint " & Chan, 3
        End If
        Exit Do
      End If
    Loop
  End If
End Sub

Sub UnBan(Chan, HMask)
  SendLine "MODE " & Chan & " -b " & HMask, 1
End Sub

Function Trim3(Text)
  Do While InStr(Text, "  "): Text = Replace(Text, "  ", " "): Loop
  Trim3 = Trim(Text)
End Function

doublestyle

29.01.2006, 19:33 Uhr
genau soetwas hab ich gesucht !

finde wenn der user die warnung ignoriert sollte er danach gekickt werden..

doublestyle

31.01.2006, 23:36 Uhr
hätte noch ne idee für des script..
es sollte auch auf [r] reagieren.. und ne kleine sache, die erlaubten chans musste ich alle doppelt hinzufügen einmal #chan und einmal #chan, weil mein vip machal sagt vip aus #chan1, #chan2 gesichtet..

und bei dem mit dem , auf den reagiert das script dann trotzdem..

Christian

31.01.2006, 23:59 Uhr
jo weil auch viele leute ihere channels bescheuerte namen geben ^^
#h.a.l.l.o

und was weiß ich was ka was ich da machen soll evtl könnte ich was einbauen evtl könntest du aber auch einfach nur das komma in der vip msg wegmachen *fg*

doublestyle

01.02.2006, 00:37 Uhr
naja die message kann ich net ändern is nen gesponserter bot ^^ aber hab jetz rausgenommen das der die chans anzeigt..

aber das mit dem [r] wär gut, oder einfach ne funktion wo man einstellen kann was nicht gesagt werden darf.. dann kann man selbst noch www. usw hinzufüge wenn man will..

LG

doublestyle

01.02.2006, 00:37 Uhr
deleted

Christian

01.02.2006, 08:50 Uhr
doublestyle schrieb:
Zitat:naja die message kann ich net ändern is nen gesponserter bot ^^ aber hab jetz rausgenommen das der die chans anzeigt..

aber das mit dem [r] wär gut, oder einfach ne funktion wo man einstellen kann was nicht gesagt werden darf.. dann kann man selbst noch www. usw hinzufüge wenn man will..

LG

Und was sollte das jetzt?

doublestyle

01.02.2006, 08:53 Uhr
forum hatte irgend nen error als ich gepostet hatte irgendwas mit sql.. hab ich net gesehn das das dann nen doppelpost wurde..

firstjoe

01.02.2006, 21:56 Uhr
double...wegen deiner [r] sache...such mal hier oder auf der page nach dem blackword script...denke das hilft dir da weiter

Firefox

08.02.2006, 20:55 Uhr
Ey Christian du hast dich verschrieben !

hier :

Code:
WriteINIString Chan, "Adertise", "0", INI

Das Adertise muss man umändern in Advertise !!
(Sonst kann man die "Rache" nicht ausschalten !!!!)
Seiten: 1 2
AnGelBot-Portal² > Scripting > Scriptreleases > AntiAd Script v1.00 by Spiky
Referenz-URLs